291 lines
13 KiB
Text
291 lines
13 KiB
Text
-- --------------------------------------------------------------------------------------------------------------
|
|
-- | BASIC LOGIC |
|
|
-- --------------------------------------------------------------------------------------------------------------
|
|
|
|
@include logic.pg
|
|
|
|
-- --------------------------------------------------------------------------------------------------------------
|
|
-- | BASIC DEFINITIONS |
|
|
-- --------------------------------------------------------------------------------------------------------------
|
|
|
|
section BasicDefinitions
|
|
|
|
-- note we leave off the type ascriptions for most of these, as the type isn't
|
|
-- very interesting
|
|
-- I'd always strongly recommend including the type ascriptions for theorems
|
|
|
|
-- Fix some set A
|
|
variable (A : ★);
|
|
|
|
-- a unary operation is a function `A → A`
|
|
def unop := A → A;
|
|
|
|
-- a binary operation is a function `A → A → A`
|
|
def binop := A → A → A;
|
|
|
|
-- fix some binary operation `*`
|
|
variable (* : binop);
|
|
infixl 20 *;
|
|
|
|
-- it is associative if ...
|
|
def assoc := forall (a b c : A), eq A (a * (b * c)) (a * b * c);
|
|
|
|
-- fix some element `e`
|
|
variable (e : A);
|
|
|
|
-- it is a left identity with respect to binop `op` if `∀ a, e * a = a`
|
|
def id_l := forall (a : A), eq A (e * a) a;
|
|
|
|
-- likewise for right identity
|
|
def id_r := forall (a : A), eq A (a * e) a;
|
|
|
|
-- an element is an identity element if it is both a left and right identity
|
|
def id := id_l ∧ id_r;
|
|
|
|
-- b is a left inverse for a if `b * a = e`
|
|
-- NOTE: we don't require `e` to be an identity in this definition.
|
|
-- this definition is purely for convenience's sake
|
|
def inv_l (a b : A) := eq A (b * a) e;
|
|
|
|
-- likewise for right inverse
|
|
def inv_r (a b : A) := eq A (a * b) e;
|
|
|
|
-- and full-on inverse
|
|
def inv (a b : A) := inv_l a b ∧ inv_r a b;
|
|
|
|
end BasicDefinitions
|
|
|
|
-- --------------------------------------------------------------------------------------------------------------
|
|
-- | ALGEBRAIC STRUCTURES |
|
|
-- --------------------------------------------------------------------------------------------------------------
|
|
|
|
-- NOTE: I want to define opposite semigroups, monoids, groups, etc. and prove
|
|
-- that they are still semigroups, monoids, etc. in order to get dual results
|
|
-- like `cancel_r` after having proved `cancel_l` for free. Unfortunately, this
|
|
-- is a bit awkward in perga, at least for now.
|
|
section Semigroup
|
|
variable (S : ★) (* : binop S);
|
|
|
|
def semigroup := assoc S (*);
|
|
end Semigroup
|
|
|
|
section Monoid
|
|
-- Let `M` be a set with binary operation `*` and element `e`.
|
|
variable (M : ★) (* : binop M) (e : M);
|
|
infixl 50 *;
|
|
|
|
-- a set `M` with binary operation `(*)` and element `e` is a monoid
|
|
def monoid : ★ := (semigroup M (*)) ∧ (id M (*) e);
|
|
|
|
-- Suppose `(M, *, e)` is a monoid
|
|
hypothesis (Hmonoid : monoid);
|
|
|
|
-- some "getters" for `monoid` so we don't have to do a bunch of very verbose
|
|
-- and-eliminations every time we want to use something
|
|
def id_lm : id_l M (*) e :=
|
|
and_elim_l (id_l M (*) e) (id_r M (*) e)
|
|
(and_elim_r (semigroup M (*)) (id M (*) e) Hmonoid);
|
|
|
|
def id_rm : id_r M (*) e :=
|
|
and_elim_r (id_l M (*) e) (id_r M (*) e)
|
|
(and_elim_r (semigroup M (*)) (id M (*) e) Hmonoid);
|
|
|
|
def assoc_m : assoc M (*) := and_elim_l (semigroup M (*)) (id M (*) e) Hmonoid;
|
|
|
|
-- now we can prove that, for any monoid, if `a` is a left identity, then it
|
|
-- must be "the" identity
|
|
def monoid_id_l_implies_identity (a : M) (H : id_l M (*) a) : eq M a e :=
|
|
-- WTS a = a * e = e
|
|
-- we can use `eq_trans` to glue proofs of `a = a * e` and `a * e = e` together
|
|
eq_trans M a (a * e) e
|
|
|
|
-- first, `a = a * e`, but we'll use `eq_sym` to flip it around
|
|
(eq_sym M (a * e) a
|
|
-- now the goal is to show `a * e = a`, which follows immediately from `id_r`
|
|
(id_rm a))
|
|
|
|
-- now we need to show that `a * e = e`, but this immediately follows from `H`
|
|
(H e);
|
|
|
|
-- the analogous result for right identities
|
|
def monoid_id_r_implies_identity (a : M) (H : id_r M (*) a) : eq M a e :=
|
|
-- this time, we'll show `a = e * a = e`
|
|
eq_trans M a (e * a) e
|
|
|
|
-- first, `a = e * a`
|
|
(eq_sym M (e * a) a
|
|
-- this time, it immediately follows from `id_l`
|
|
(id_lm a))
|
|
|
|
-- and `e * a = e`
|
|
(H e);
|
|
end Monoid
|
|
|
|
section Group
|
|
|
|
variable (G : ★) (* : binop G) (e : G) (i : unop G);
|
|
|
|
infixl 50 *;
|
|
|
|
-- groups are just monoids with inverses
|
|
def has_inverses : ★ := forall (a : G), inv G (*) e a (i a);
|
|
|
|
def group : ★ := (monoid G (*) e) ∧ has_inverses;
|
|
|
|
hypothesis (Hgroup : group);
|
|
|
|
-- more "getters"
|
|
def monoid_g : monoid G (*) e := and_elim_l (monoid G (*) e) has_inverses Hgroup;
|
|
def assoc_g : assoc G (*) := assoc_m G (*) e monoid_g;
|
|
def id_lg : id_l G (*) e := id_lm G (*) e (and_elim_l (monoid G (*) e) has_inverses Hgroup);
|
|
def id_rg : id_r G (*) e := id_rm G (*) e (and_elim_l (monoid G (*) e) has_inverses Hgroup);
|
|
def inv_g : forall (a : G), inv G (*) e a (i a) := and_elim_r (monoid G (*) e) has_inverses Hgroup;
|
|
def left_inverse (a b : G) := inv_l G (*) e a b;
|
|
def right_inverse (a b : G) := inv_r G (*) e a b;
|
|
def inv_lg (a : G) : left_inverse a (i a) := and_elim_l (inv_l G (*) e a (i a)) (inv_r G (*) e a (i a)) (inv_g a);
|
|
def inv_rg (a : G) : right_inverse a (i a) := and_elim_r (inv_l G (*) e a (i a)) (inv_r G (*) e a (i a)) (inv_g a);
|
|
|
|
def = := eq G;
|
|
infixl 10 =;
|
|
|
|
-- An interesting theorem: left inverses are unique, i.e. if b * a = e, then b = a^-1
|
|
def left_inv_unique (a b : G) (h : left_inverse a b) : b = (i a) :=
|
|
-- b = b * e
|
|
-- = b * (a * a^-1)
|
|
-- = (b * a) * a^-1
|
|
-- = e * a^-1
|
|
-- = a^-1
|
|
eq_trans G b (b * e) (i a)
|
|
(eq_sym G (b * e) b (id_rg b))
|
|
(eq_trans G (b * e) (b * (a * i a)) (i a)
|
|
(eq_cong G G e (a * i a) ((*) b)
|
|
(eq_sym G (a * i a) e (inv_rg a)))
|
|
(eq_trans G (b * (a * i a)) (b * a * i a) (i a)
|
|
(assoc_g b a (i a))
|
|
(eq_trans G (b * a * i a) (e * i a) (i a)
|
|
(eq_cong G G (b * a) e (fun (x : G) => x * i a) h)
|
|
(id_lg (i a)))));
|
|
|
|
-- And so are right inverses
|
|
def right_inv_unique (a b : G) (h : right_inverse a b) : b = (i a) :=
|
|
-- b = e * b
|
|
-- = (a^-1 * a) * b
|
|
-- = a^-1 * (a * b)
|
|
-- = a^-1 * e
|
|
-- = a^-1
|
|
eq_trans G b (e * b) (i a)
|
|
(eq_sym G (e * b) b (id_lg b))
|
|
(eq_trans G (e * b) (i a * a * b) (i a)
|
|
(eq_cong G G e (i a * a) (fun (x : G) => x * b)
|
|
(eq_sym G (i a * a) e (inv_lg a)))
|
|
(eq_trans G (i a * a * b) (i a * (a * b)) (i a)
|
|
(eq_sym G (i a * (a * b)) (i a * a * b) (assoc_g (i a) a b))
|
|
(eq_trans G (i a * (a * b)) (i a * e) (i a)
|
|
(eq_cong G G (a * b) e ((*) (i a)) h)
|
|
(id_rg (i a)))));
|
|
|
|
-- (a^-1)^-1 = a
|
|
def inverse_involutive (a : G) : i (i a) = a :=
|
|
eq_sym G a (i (i a)) (right_inv_unique (i a) a (inv_lg a));
|
|
|
|
-- the classic shoes and socks theorem, namely that (a * b)^-1 = b^-1 * a^-1
|
|
def shoes_and_socks (a b : G) : i (a * b) = i b * i a :=
|
|
eq_sym G (i b * i a) (i (a * b))
|
|
(right_inv_unique (a * b) (i b * i a)
|
|
(let
|
|
-- helper function to prove that x * a^-1 = y * a^-1 given x = y
|
|
(under_ai (x y : G) (h : x = y) := eq_cong G G x y (fun (z : G) => z * (i a)) h)
|
|
in
|
|
-- (a * b) * (b^-1 * a^-1) = ((a * b) * b^-1) * a^-1
|
|
-- = (a * (b * b^-1)) * a^-1
|
|
-- = (a * e) * a^-1
|
|
-- = a * a^-1
|
|
-- = e
|
|
eq_trans G (a * b * (i b * i a)) (a * b * i b * i a) e
|
|
(assoc_g (a * b) (i b) (i a))
|
|
(eq_trans G (a * b * i b * i a) (a * (b * i b) * i a) e
|
|
(under_ai (a * b * i b) (a * (b * i b)) (eq_sym G (a * (b * i b)) (a * b * i b) (assoc_g a b (i b))))
|
|
(eq_trans G (a * (b * i b) * i a) (a * e * i a) e
|
|
(eq_cong G G (b * i b) e (fun (x : G) => (a * x * i a)) (inv_rg b))
|
|
(eq_trans G (a * e * i a) (a * i a) e
|
|
(under_ai (a * e) a (id_rg a))
|
|
(inv_rg a))))
|
|
end));
|
|
|
|
def cancel_l (a b c : G) : a * b = a * c → b = c :=
|
|
fun (h : a * b = a * c) =>
|
|
eq_trans G b (e * b) c
|
|
(eq_sym G (e * b) b (id_lg b))
|
|
(eq_trans G (e * b) (i a * a * b) c
|
|
(eq_cong G G e (i a * a) ([x : G] x * b)
|
|
(eq_sym G (i a * a) e (inv_lg a)))
|
|
(eq_trans G (i a * a * b) (i a * (a * b)) c
|
|
(eq_sym G (i a * (a * b)) (i a * a * b) (assoc_g (i a) a b))
|
|
(eq_trans G (i a * (a * b)) (i a * (a * c)) c
|
|
(eq_cong G G (a * b) (a * c) ((*) (i a)) h)
|
|
(eq_trans G (i a * (a * c)) (i a * a * c) c
|
|
(assoc_g (i a) a c)
|
|
(eq_trans G (i a * a * c) (e * c) c
|
|
(eq_cong G G (i a * a) e ([x : G] x * c) (inv_lg a))
|
|
(id_lg c))))));
|
|
|
|
def cancel_r (a b c : G) : b * a = c * a → b = c :=
|
|
fun (h : b * a = c * a) =>
|
|
eq_trans G b (b * e) c
|
|
(eq_sym G (b * e) b (id_rg b))
|
|
(eq_trans G (b * e) (b * (a * i a)) c
|
|
(eq_cong G G e (a * i a) ((*) b)
|
|
(eq_sym G (a * i a) e (inv_rg a)))
|
|
(eq_trans G (b * (a * i a)) (b * a * i a) c
|
|
(assoc_g b a (i a))
|
|
(eq_trans G (b * a * i a) (c * a * i a) c
|
|
(eq_cong G G (b * a) (c * a) ([x : G] x * i a) h)
|
|
(eq_trans G (c * a * i a) (c * (a * i a)) c
|
|
(eq_sym G (c * (a * i a)) (c * a * i a) (assoc_g c a (i a)))
|
|
(eq_trans G (c * (a * i a)) (c * e) c
|
|
(eq_cong G G (a * i a) e ((*) c) (inv_rg a))
|
|
(id_rg c))))));
|
|
|
|
def abelian : ★ := forall (a b : G), a * b = b * a;
|
|
|
|
def left_right_cancel : (forall (x y z : G), x * y = z * x → y = z) → abelian :=
|
|
fun (h : forall (x y z : G), x * y = z * x → y = z) (a b : G) =>
|
|
h (i a) (a * b) (b * a)
|
|
(eq_trans G (i a * (a * b)) (i a * a * b) (b * a * i a)
|
|
(assoc_g (i a) a b)
|
|
(eq_trans G (i a * a * b) (e * b) (b * a * i a)
|
|
(eq_cong G G (i a * a) e ([x : G] x * b) (inv_lg a))
|
|
(eq_trans G (e * b) b (b * a * i a)
|
|
(id_lg b)
|
|
(eq_trans G b (b * e) (b * a * i a)
|
|
(eq_sym G (b * e) b (id_rg b))
|
|
(eq_trans G (b * e) (b * (a * i a)) (b * a * i a)
|
|
(eq_cong G G e (a * i a) ((*) b) (eq_sym G (a * i a) e (inv_rg a)))
|
|
(assoc_g b a (i a)))))));
|
|
|
|
def inv_distrib_abelian : (forall (a b : G), i (a * b) = i a * i b) → abelian :=
|
|
fun (h : forall (a b : G), i (a * b) = i a * i b) (a b : G) =>
|
|
eq_trans G (a * b) (i (i a) * b) (b * a)
|
|
(eq_cong G G a (i (i a)) ([x : G] x * b) (eq_sym G (i (i a)) a (inverse_involutive a)))
|
|
(eq_trans G (i (i a) * b) (i (i a) * i (i b)) (b * a)
|
|
(eq_cong G G b (i (i b)) ((*) (i (i a))) (eq_sym G (i (i b)) b (inverse_involutive b)))
|
|
(eq_trans G (i (i a) * i (i b)) (i (i b * i a)) (b * a)
|
|
(eq_sym G (i (i b * i a)) (i (i a) * i (i b)) (shoes_and_socks (i b) (i a)))
|
|
(eq_trans G (i (i b * i a)) (i (i b) * i (i a)) (b * a)
|
|
(h (i b) (i a))
|
|
(eq_trans G (i (i b) * i (i a)) (b * i (i a)) (b * a)
|
|
(eq_cong G G (i (i b)) b ([x : G] x * i (i a)) (inverse_involutive b))
|
|
(eq_cong G G (i (i a)) a ((*) b) (inverse_involutive a))))));
|
|
|
|
def order_two (a : G) : a * a = e → a = i a := right_inv_unique a a;
|
|
|
|
def all_order_two_abelian : (forall (a : G), a * a = e) → abelian :=
|
|
fun (h : forall (a : G), a * a = e) =>
|
|
inv_distrib_abelian (fun (a b : G) =>
|
|
(eq_trans G (i (a * b)) (a * b) (i a * i b)
|
|
(eq_sym G (a * b) (i (a * b)) (order_two (a * b) (h (a * b))))
|
|
(eq_trans G (a * b) (a * i b) (i a * i b)
|
|
(eq_cong G G b (i b) ((*) a) (order_two b (h b)))
|
|
(eq_cong G G a (i a) ([x : G] x * i b) (order_two a (h a))))));
|
|
|
|
end Group
|